Metadata in XHTML - XSLTによる抽出

Namespace: 名前空間と接頭辞のマッピングを生かすXSLT

Prefixed attribute values can be transformed into RDF properties via XSLT. The templates are little bit complex, but can be applied to any vocabulary without prior knowledge.

名前空間と接頭辞をマッピングしてプロパティを記述しているので、ここからRDFのプロパティを生成することが可能です。適切なRDFを生成するXSLTのテンプレートを考えてみましょう。まず、schemaのURIを記述しているlink要素を集めて、簡単にアクセスできるようにグローバル変数に割り当てておきます。

<xsl:variable name="schemas"
     select="/h:html/h:head/h:link[starts-with(@rel,'schema.')]"/>

meta要素を処理するテンプレートでは、name属性が接頭辞を持つ（ピリオドを含む）場合、name属性値とこの変数を使って、プロパティの名前と名前空間を決定します。

<xsl:template match="h:meta[contains(@name,'.')]">
 <xsl:variable name="pfx" select="substring-before(@name,'.')"/>
 <xsl:variable name="ns" select="$schemas[@rel=concat('schema.',$pfx)]/@href"/>
 <xsl:element name="{translate(@name,'.',':')}" namespace="{$ns}">
  <xsl:value-of select="@content"/>
 </xsl:element>
</xsl:template>

link要素に対しても同様の考え方でRDFを生成するXSLTテンプレートを記述できます。これらを適用すると、例のmeta、link要素からは次のようなRDFを得ることができます。

<rdf:Description rdf:about="">
 <dc:creator xmlns:dc="http://purl.org/dc/elements/1.1/">Masahide Kanzaki</dc:creator>
 <dcterms:created xmlns:dcterms="http://purl.org/dc/terms/">2003-12-15</dcterms:created>
 <cc:license xmlns:cc="http://web.resource.org/cc/"
   rdf:resource="http://creativecommons.org/licenses/by-nc-sa/1.0/"/>
</rdf:Description>

xsl:elementのnameは、ローカル名（名前空間修飾なし）でも構わないのですが、ここでは「.」を「:」に変換し、敢えてQName（接頭辞つき）としています。これによって、RDFプロパティの接頭辞も（ns_1:などではなく）馴染みのあるものにできますし、よく使う名前空間をXSLT自身で宣言していれば、結果ツリーのルート要素にその名前空間がコピーされるので、それに対応するプロパティ要素はxmlns:dcなどの宣言属性がない、すっきりした形になります。

dfn要素によるキーワード

The simplest way is that uses existing elements to denote 'subject' or topic of the document. For example, it is natural to extract a keyword term from XHML 'dfn' elements. It will be mapped to a URI and disambiguated by finding Wikipedia definitions.

一番シンプルなのは、特定のXHTML要素でマークされた語句をキーワードとして扱う方法です。ここでは、語句の定義を意味するdfn要素からキーワードを取り出し、URIにマッピングすることを考えましょう。

<xsl:template match="h:dfn">
  <kw:hasKeyword>
   <kw:Keyword rdf:about="{concat('http://purl.org/net/ns/keyword/',.)}"/>
  </kw:hasKeyword>
</xsl:template>

このテンプレートを、meta要素やlink要素を処理するのと合わせて呼び出せば、例6のrdf:Descriptionに、本文のキーワードがkw:hasKeywordとして列挙されます。文字列としてのキーワードは多義語や同義語のあいまいさがあるので、http://purl.org/net/ns/keyword/にマップし、Wikipediaなどを使って曖昧さ解決を試みます。

Class: 接頭辞つきクラス属性を使う

Prefixed attributes approach can be extended to any elements in the XHTML body. A good candidate is class attribute, which is available for most elements, and is originally designed for classifying elements. The idea of XSLT template is almost the same as that extracts RDF from 'meta' element.

meta要素のname属性値を接頭辞付きとすることでプロパティを明確にしたのと同様な方法を、本文にも導入してみましょう。class属性はどんな要素型にでも使えるので、これを利用すれば、任意の要素をメタデータにすることができます。例えば、本文末尾などに作成日付、更新日付を記述している場合。

[Ex.10]
<address>Original: <em class="dcterms.created">2003-12-15</em>; Last-modified: <em class="dcterms.modified">2004-03-14</em></address>

meta要素の場合とほとんど同様のテンプレートで、これらに対応するdcterms:created、dcterms:modifiedといったプロパティ要素を生成できます（名前空間はlink要素でマップしてあるものとします）。

<xsl:template match="*[contains(@class,'.')]">
 <xsl:variable name="pfx" select="substring-before(@class,'.')"/>
 <xsl:variable name="ns" select="$schemas[@rel=concat('schema.',$pfx)]/@href"/>
 <xsl:element name="{translate(@class,'.',':')}" namespace="{$ns}">
  <xsl:value-of select="."/>
 </xsl:element>
</xsl:template>

テンプレートのmatch部分で、要素型名自身は「*」となっているので、どんな要素でも接頭辞つきclassを与えればメタデータにできることに注意してください。

a要素のrel属性を利用したメタデータ

The prefixed rel attributes with link elements generate 'resource' object node in RDF. The same method can be applied to 'a' elements in the body. In the following example, the document is assumed to be a translated version of the New York Times article.

link要素のrel属性を使ってリソース型メタデータを記述した方法は、本文ではa要素に応用することができます。たとえば、ある文書が別の文書の翻訳版である場合は次のような情報を記述するでしょう。

[Ex.12]
<p>この文書は<a rel="prism.isTranslationOf" href="http://www.nytimes.com/2003/12/14/arts/...">2003年12月14日付The New York Times</a>の翻訳版です。</p>

ここでは、オリジナルへのリンクに、出版物のメタデータを記述する語彙であるPRISMを使って、prism.isTranslationOfという関係を示しています（接頭辞prismには、link要素で名前空間をマップしてあるものとします）。これまでと同様のテンプレートを使って、次のようなRDFを生成できます。

<rdf:Description rdf:about="">
 ...
 <prism:isTranslationOf xmlns:prism="http://prismstandard.org/namespaces/basic/1.0/"
   rdf:resource="http://www.nytimes.com/2003/12/14/arts/..."
   rdfs:label="2003年12月14日付The New York Times"/>
</rdf:Description>

Inverse Functional Propertyとしてのホームページ

We can extract 'resource' uri from 'a' elements with prefixed 'rel' value. Sometimes, these uri denote the resource themselves (e.g. the original page of the translation). However, those often describe the 'homepage' of the resources, working as the Inverse Functional Property. In order to distinguish them, here we use class="ifp" for latter type of 'a' elements. Resulting RDF property will have rdf:parseType="Resource", hence generate blank node and give 'foaf:homepage' to that bnode.

a要素とrel属性を組み合わせてリソース型プロパティを記述する時、href属性は必ずしもそのリソース自身のURIであるとは限りません。たとえば、Relationship vocabularyを用いて <a rel="relship.acquaintanceOf" href="http://www.kanzaki.com/norrington/">Sir Roger Norrington</a> と書いた場合、このURIは Sir Roger Norringtonという人物そのものではなく、彼の「ホームページ」に相当します。つまり、relship.acquaintanceOf要素のrdf:resourceではなく、relship.acquaintanceOfの目的語であるfoaf:Personのurlでなければなりません（foaf:Personとfoaf:mboxの関係と同様です）。

話が複雑になってしまいますが、これらを区別するために、ここではこういったa要素には、class="ifp"を設定し、そのURIが目的語リソースのIFPであると示すことにます。

[Ex.17]
<p>I know <a rel="relship.acquaintanceOf" class="ifp" href="http://www.kanzaki.com/norrington/">Sir Roger Norrington</a>.</p>

これを処理するために、条件分岐を加えたテンプレートを用意します。

<xsl:template match="h:a[contains(@rel,'.')]">
 <xsl:variable name="pfx" select="substring-before(@rel,'.')"/>
 <xsl:variable name="ns" select="$schemas[@rel=concat('schema.',$pfx)]/@href"/>
 <xsl:element name="{translate(@rel,'.',':')}" namespace="{$ns}">
  <xsl:choose>
   <xsl:when test="@class='ifp'">
    <xsl:attribute name="rdf:parseType">Resource</xsl:attribute>
    <foaf:homepage rdf:resource="{@href}"/>
    <rdfs:label><xsl:value-of select="."/></rdfs:label>
   </xsl:when>
   <xsl:otherwise>
    <xsl:attribute name="rdf:resource"><xsl:value-of select="@href"/></xsl:attribute>
    <xsl:attribute name="rdfs:label"><xsl:value-of select="."/></xsl:attribute>
   </xsl:otherwise>
  </xsl:choose>
 </xsl:element>
</xsl:template>

適用すると、次のように空白ノードを持つRDFが生成されます。

<rdf:Description rdf:about="">
 ...
 <foaf:maker>
  <foaf:Person rdf:nodeID="me">
   <foaf:mbox rdf:resource="mailto:webmaster@kanzaki.com"/>
   ...
   <relship:acquaintanceOf
        xmlns:relship="http://purl.org/vocab/relationship/"
        rdf:parseType="Resource">
    <foaf:homepage rdf:resource="http://www.kanzaki.com/norrington/"/>
    <rdfs:label>Sir Roger Norrington</rdfs:label>
   </relship:acquaintanceOf>
  </foaf:Person>
 </foaf:maker>
</rdf:Description>

一般化するためにa要素の内容をrdfs:labelにしていますが、Relationshipのような人間関係を前提とするなら、foaf:nameとしても良いでしょう。

meta要素

link要素

次の@relを持つとき、@hrefの値を目的語リソースにして文書のプロパティを生成

@class属性値

@rel属性値

microformats

If a block element has a class attribute values eiher of vcard, vevent, hreview, then the content will be treated as microformat, and will generate appropriate RDF graph.

ブロックレベル要素にvcard, vevent, hreviewのいずれかの@classがあれば、その内部をそれぞれのmicroformatで定める名前によって処理。通常のmetaprofのルールは適用せず、名前は全てそのmicroformatに従うものとし、孫要素もプロパティとして処理する。

GRDDLによるXSLTの指定

In order to specify the location of XSLT, we can use GRDDL approach. This page itself is an example of GRDDL processing.

せっかくXHTMLにメタデータを加え、それを抽出するためのXSLTも設計するのですから、このXSLTの存在をアプリケーション一般に伝えて、RDFを生成してもらいたいもの。現在検討されている Gleaning Resource Descriptions from Dialects of Languages [GRDDL] は、適用するXSLTを示す汎用的な方法です。

抽出XSLTにhttp://www.kanzaki.com/parts/xh2rdf.xslを使うとすると、GRDDLを記述するhead要素部分は以下のようになります。

<head profile="http://www.w3.org/2003/g/data-view">
 <title>....</title>
 <link rel="transformation" href="http://www.kanzaki.com/parts/xh2rdf.xsl" />
 ...

必要なのは、head要素にGRDDLを示すprofileを記述するのと、link要素でrel="transformation"としてXSLTのURIを与えることだけ。独自のXSLTを作ったら、このlink要素のhref属性をそれに合わせて書き換えます。このページ自身がGRDDLによるメタデータ抽出の例となっています。

Alternatively, you can use a profile which in turn specifies the location of XSLT, so that GRDDL works without 'transformation' link. 'http://purl.org/net/ns/metaprof' is an example of such profile.

なお、head要素のprofile属性で示した「プロファイル」でRDDLを使ってXSLTを指定しておくと、GRDDLはそのスタイルシートを使ってRDFを抽出します（つまり、link要素によるtransfer指定が不要になる）。たとえば、この文書で示したメタデータを記述するためのプロファイルは、http://purl.org/net/ns/metaprofで定義しているので、次のようにできます。

<head profile="http://purl.org/net/ns/metaprof">
 <title>....</title>
 ...

profile属性を用いたGRDDLの利用については、「profile属性でのGRDDL指定」を参照してください。

CSSを使って本文中のメタデータを顕在化させる

By using CSS, metadata in the body will become available to human readers as well as agents.

メタデータはマシンだけのためのものではありません。接頭辞付き属性でマーク付けした箇所をCSSを使ってハイライトすれば、人間の読者にとっても有益な情報を提供できます。たとえば、class="dc.title"とクラス指定した部分に背景色を与えるとすれば、次のようなCSS宣言を用います。

[Ex.24] .dc\.title {background: #ffd}

ピリオド「.」はCSSのセレクタで直接使うことができないので、「\」を使ってエスケープします。rel属性の場合は、CSS2の属性値セレクタを利用します。

[Ex.25] a[rel~="relship\.acquaintanceOf"] {background: #cfc}

残念ながらこの属性値セレクタは認識できないブラウザが多いので、今すぐの効果はあまり大きくありませんが、可能性はとても面白いものを持っています。

Simpler approach: より簡単な方法

Mapping prefixes to schema uris via link elements would be a little bit cumbersome if only limited set of vocabularies is used across the entire site. By defining those mapping in the XSLT, it's possible to skip link declarations in each XHTML file, and template will be simpler. This sacrifices the generality of XSLT, but will make things easier in some cases.

link要素で名前空間と接頭辞を結びつけるのは、アプリケーションに予備知識が無くてもさまざまな語彙を追加できるというメリットがありますが、XSLTが若干複雑になり、毎回link要素を加えるという（少しではあるものの）手間がかかります。メタデータをマーク付けは、Dublin Core、FOAFなどある程度限られた語彙でおおむね間に合いますから、これらの名前空間を最初からXSLTで宣言しておき、XHTMLではマッピングを省略するという方法をとれば、仕組みは簡単になります。

例5のmeta要素からRDFを生成するテンプレートは、名前空間が定義済であるとすれば次のように単純化できます。

<xsl:template match="h:meta[contains(@name,'.')]">
 <xsl:element name="{translate(@name,'.',':')}">
  <xsl:value-of select="@content"/>
 </xsl:element>
</xsl:template>

ほかのrel属性やclass属性を用いるものも、同様にテンプレートを簡略化できます。XHTMLでのマーク付けは、（link要素による名前空間マッピングは省略できますが）これまで述べたのと同じ方法です。